Question

Jenkinsfile 主动选择参数

2018-12-19

20565

jenkins jenkins-pipeline

如何在 Multibranch Pipeline Jenkinsfile（声明式）中使用此 dsl 脚本？

parameters {
    activeChoiceParam('States') {
        description('Select a state option')
        filterable()
        choiceType('SINGLE_SELECT')
        groovyScript {
            script('["Sao Paulo", "Rio de Janeiro", "Parana:selected", "Acre"]')
            fallbackScript('return ["ERROR"]')
        }
    }
    activeChoiceReactiveParam('Cities') {
        description('Active Choices Reactive parameter')
        filterable()
        choiceType('CHECKBOX')
        groovyScript {
            script('''
if (States.equals('Sao Paulo')) {
    return ['Barretos', 'Sao Paulo', 'Itu'];
} else if (States.equals('Rio de Janeiro')) {
    return ['Rio de Janeiro', 'Mangaratiba']
} else if (States.equals('Parana')) {
    return ['Curitiba', 'Ponta Grossa']
} else if (States.equals('Acre')) {
    return ['Rio Branco', 'Acrelandia']
} else {
    return ['Unknown state']
}
                       ''')
            fallbackScript('return ["Script error!"]')
        }
        referencedParameter('States')
    }
}

当我在 Jenkinsfile 中使用此脚本时出现此错误：

WorkflowScript: 23: Build parameters definitions cannot have blocks @ line 23, column 5.
       activeChoiceParam('States') {
       ^

WorkflowScript: 32: Build parameters definitions cannot have blocks @ line 32, column 9.
           activeChoiceReactiveParam('Cities') {
           ^

2 errors

    at org.codehaus.groovy.control.ErrorCollector.failIfErrors(ErrorCollector.java:310)
    at org.codehaus.groovy.control.CompilationUnit.applyToPrimaryClassNodes(CompilationUnit.java:1085)
    at org.codehaus.groovy.control.CompilationUnit.doPhaseOperation(CompilationUnit.java:603)
    at org.codehaus.groovy.control.CompilationUnit.processPhaseOperations(CompilationUnit.java:581)
    at org.codehaus.groovy.control.CompilationUnit.compile(CompilationUnit.java:558)
    at groovy.lang.GroovyClassLoader.doParseClass(GroovyClassLoader.java:298)
    at groovy.lang.GroovyClassLoader.parseClass(GroovyClassLoader.java:268)
    at groovy.lang.GroovyShell.parseClass(GroovyShell.java:688)
    at groovy.lang.GroovyShell.parse(GroovyShell.java:700)
    at org.jenkinsci.plugins.workflow.cps.CpsGroovyShell.doParse(CpsGroovyShell.java:131)
    at org.jenkinsci.plugins.workflow.cps.CpsGroovyShell.reparse(CpsGroovyShell.java:125)
    at org.jenkinsci.plugins.workflow.cps.CpsFlowExecution.parseScript(CpsFlowExecution.java:560)
    at org.jenkinsci.plugins.workflow.cps.CpsFlowExecution.start(CpsFlowExecution.java:521)
    at org.jenkinsci.plugins.workflow.job.WorkflowRun.run(WorkflowRun.java:325)
    at hudson.model.ResourceController.execute(ResourceController.java:97)
    at hudson.model.Executor.run(Executor.java:429)
Finished: FAILURE

Answer 1

在 Jenkins 领域特定语言 (DSL) 期间，在声明式 Jenkinsfile 中使用 Active Choices 插件时会发生此错误。开发人员表示，不支持此功能。

这种插件的整个安排改变了所有权，并留下了充满垃圾信息的过时 wiki 页面，这会导致在数十个地方搜索相关信息（包括充斥着“感谢”/“ping”的垃圾评论部分）时浪费大量时间。

Answer 2

我按照如下方法解决了该问题：

properties([ 
    parameters([
        [
            $class: 'ChoiceParameter', 
            choiceType: 'PT_SINGLE_SELECT', 
            description: 'Select a choice', 
            filterLength: 1, 
            filterable: true, 
            name: 'choice1', 
            randomName: 'choice-parameter-7601235200970', 
            script: [
                $class: 'GroovyScript', 
                fallbackScript: [
                    classpath: [], 
                    sandbox: false, 
                    script: 'return ["ERROR"]'
                ], 
                script: [
                    classpath: [], 
                    sandbox: false, 
                    script: 'return[\'aaa\',\'bbb\']'
                ]
            ]
        ], 
        [
            $class: 'CascadeChoiceParameter', 
            choiceType: 'PT_SINGLE_SELECT', 
            description: 'Active Choices Reactive parameter', 
            filterLength: 1, 
            filterable: true, 
            name: 'choice2', 
            randomName: 'choice-parameter-7601237141171', 
            referencedParameters: 'choice1', 
            script: [
                $class: 'GroovyScript', 
                fallbackScript: [
                    classpath: [], 
                    sandbox: false, 
                    script: 'return ["error"]'
                ], 
                script: [
                    classpath: [], 
                    sandbox: false, 
                    script: 'if(choice1.equals("aaa")){return [\'a\', \'b\']} else {return [\'aaaaaa\',\'fffffff\']}'
                ]
            ]
        ]
    ])
])

Answer 3

要在声明式管道中使用主动选择参数，您需要执行以下操作：

properties([
    parameters([
        choice(
            name: 'ENV',
            choices: [
                'dev',
                'prod'
            ]
        ),
        [$class: 'ChoiceParameter',
            choiceType: 'PT_RADIO',
            filterLength: 1,
            filterable: false,
            name: 'CHOICES',
            script: [
                $class: 'GroovyScript',
                fallbackScript: [
                    classpath: [],
                    sandbox: false,
                    script: 'return ["Check Jenkins ScriptApproval page"]'
                ],
                script: [
                    classpath: [],
                    sandbox: false,
                    script: 'return ["One","Two:selected"]'
                ]
            ]
        ]
    ])
])

pipeline {
    agent any

    stages {
        stage('Print the Values') {
            steps {
                echo "Environment: ${params.ENV}"
                echo "Choice: ${params.CHOICES}"
            }
        }
    }
}