Question

如何在 Nextflow 中调用脚本中创建的变量？

2021-03-10

6147

bash bioinformatics nextflow

我有一个 nextflow 脚本，它从文本文件创建变量，我需要将该变量的值传递给命令行命令（这是一个 bioconda 包）。这两个过程发生在“脚本”部分内。我曾尝试使用“$”符号调用变量，但没有任何结果，我想是因为在 nextflow 脚本的脚本部分中使用该符号是为了调用输入部分中定义的变量。

为了更清楚起见，下面是我想要实现的代码示例：

params.gz_file = '/path/to/file.gz'
params.fa_file = '/path/to/file.fa'
params.output_dir = '/path/to/outdir'

input_file = file(params.gz_file)
fasta_file = file(params.fa_file)

process foo {
    //publishDir "${params.output_dir}", mode: 'copy',

    input:
    path file from input_file
    path fasta from fasta_file

    output:
    file ("*.html")

    script:
    """
    echo 123 > number.txt
    parameter=`cat number.txt`
    create_report $file $fasta --flanking $parameter 
    """
}

通过这样做，我收到的错误是：

Error executing process > 'foo'
Caused by:
  Unknown variable 'parameter' -- Make sure it is not misspelt and defined somewhere in the script before using it

有没有办法在脚本中调用变量 parameter ，而不会让 Nextflow 将其解释为输入文件？提前致谢！

Answer 1

有关脚本块的文档在此处很有用：

Since Nextflow uses the same Bash syntax for variable substitutions in strings, you need to manage them carefully depending on if you want to evaluate a variable in the Nextflow context - or - in the Bash environment execution.

一种解决方案是通过在 shell (Bash) 变量前添加反斜杠 ( \ ) 字符来对其进行转义，如下例所示：

process foo {

    script:
    """
    echo 123 > number.txt
    parameter="\$(cat number.txt)"
    echo "\${parameter}"
    """
}

另一种解决方案是改用 shell 块，其中美元符号 ( $ ) 变量由 shell（Bash 解释器）管理，而感叹号 ( ! ) 变量由 Nextflow 处理。例如：

process bar {

    echo true

    input:
    val greeting from 'Hello', 'Hola', 'Bonjour'

    shell:
    '''
    echo 123 > number.txt
    parameter="$(cat number.txt)"
    echo "!{greeting} parameter ${parameter}"
    '''
}

Answer 2

在顶部的“parameter”部分中声明“parameter”。

params.parameter="1234"
(..)
script:
"""
(...)
create_report $file $fasta --flanking ${params.parameter} 
(...)
"""
(...)

并使用“--parameter 87678”调用“nextflow run”